| 基於ATMEGA48與DS1302組成的定時控制系統
Atmel公司的ATMEGA48是一款高性能、低功耗的8 位AVR微處理器，使用先進的RISC 結構，大多數指令的執行時間為單個時鐘周期，所以運算速度更快。兩個具有獨立預分頻器和比較器功能的8 位定時器/ 計數器；一個具有預分頻器、比較功能和捕捉功能的16 位定時器/ 計數器；具有獨立振蕩器的實時計數器RTC；六通道PWM；8路10 位ADC(TQFP 與MLF 封裝)[ 6路10 位ADC( PDIP 封裝)]；可編程的串列USART 介面；可工作於主機/ 從機模式的SPI 串列介面；面向位元組的兩線串列介面；具有獨立片內振蕩器的可編程看門狗定時器；片內模擬比較器；引腳電平變化可引發中斷及喚醒MCU等。
其具有的下面特點無論從編程、自編程和加密等方面都給用戶提供了很大的方便。4K位元組的系統內可擦寫10,000 次的可編程Flash；具有獨立鎖定位的可選Boot 代碼區，通過片上Boot程序實現系統內編程；256位元組的擦寫100,000 次的EEPROM；512位元組的片內SRAM，可以對鎖定位進行編程以實現用戶程序的加密。
Maxim公司的8腳串列實時時鐘日曆晶元DS1302，體積小、與單片機介面簡單、工作電壓範圍寬(2.5~5.5V)、功耗低、介面容易、佔用CPU I/O口線少、可對時鐘晶元備份電池進行涓流充電等特點。所以應用方便，被很多設計者所青睞。
Maxim公司的8腳串列實時時鐘日曆晶元DS1302，體積小、與單片機介面簡單、工作電壓範圍寬(2.5~5.5V)、功耗低、介面容易、佔用CPU I/O口線少、可對時鐘晶元備份電池進行涓流充電等特點。所以應用方便，被很多設計者所青睞。
圖1 ATMEGA48與DS1302的電路連接
筆者利用這兩種晶元，設計了實時時鐘，實時數據採集和定時控制系統。現就DS1302與ATMEGA48的應用介紹給大家。
由於ATMEGA48有可選的內部振蕩器，所以只需接通電源即可；DS1302需要一個32768Hz的晶振，和一個備用電池。可以看出結構很簡單(由於本文只介紹ATMEGA48和DS1302的應用，所以其餘的顯示電路和數據採集電路均省略。)。
ATMEGA48與DS1302的通訊程序(ASM)
圖2 DS1302的時序
圖3 DS1302充電原理圖
DS1302的時序如圖2。
根據時序圖，給出下面的讀/寫程序：
讀出數據子程序如下：
;sbi portd,7 ;假設調用子程序以前已經保持rst為高
RDS: clr r17 ;將取到的數據保存到R17中
ldi r24,8
sbi portd,6 ;sclk
RDS1: cbi portd,6 ;sclk 下降沿讀取數據
nop
IN R16,pind ;從CPU I/O讀取數據
nop
sbi portd,6 ;sclk
BST R16,5 ;複製PIND.5到T
LSR R17
BLD R17,7 ;複製T到R17.7
dec r24
CPI R24,0
BRNE RDS1
RET
註： ATMEGA48 I/O口有三個寄存器分別是：數據寄存器- PORTx、數據方向寄存器- DDRx 和埠輸入引腳- PINx。I/O作為數據輸入使用時，讀取數據命令應為 IN Rd,PINx，如果使用IN Rd,PORTx則讀取到的是I/O口的狀態，儘管將DDRx設置成數據輸入。特別注意的是，讀取軟體賦予引腳電平和執行讀取指令in 之間至少有一個時鐘周期的間隔，文中用nop間隔。
寫入數據(命令/地址)子程序如下：
;ldi R17,data ;假設要寫入的數據已經存放到R17中
;sbi portd,7 ;假設調用子程序以前已經保持rst為高
WDS: ldi r24,8
WDS1: cbi portd,6 ;sclk
in r16,portd ;讀入D口狀態
BST R17,0 ;將R17.0複製到T
BLD R16,5 ;將T複製到R16.5
nop
out portd,r16 ;寫數據到portd(R16.5->portd.5)
sbi portd,6 ;sclk
lsr r17
dec r24
CPI R24,0
BRNE WDS1
RET
關於命令位元組的說明。DS1302命令位元組由8位組成，BIT 0 為1時，讀取數據，為0時寫入數據。BIT 1-5 為地址。BIT 6 為1時指向31個RAM，為0 時指向時鐘寄存器。BIT 7 必須為1，為0時將使DS1302停止。
DS1302的控制寄存器的第七位是防寫位，所以在寫入數據前應該將其關閉，並在寫數據完畢后將其使能。下面是一段完整的設置分的程序。
......
ldi r19,0x43 ;假設當前時間為43分，DS1302時間寄存器保存的數據為10進位數十六進位存儲。
ldi r18,0x82 ;寫分 命令
ldi r27,0x00 ;x H
ldi r26,19 ;x L 在這裡使用間接定址，所以只需改變R19的數據即可。
......
WRITE_DS1302:
cbi portd,7
cbi portd,6
sbi portd,7
ldi r17,0x8e ;控制寄存器en_WRITE
rCALL WDS
ldi r17,0 ;寫操作前WP=0
rCALL WDS
mov r17,r18 ;寫秒 分 時 日 月 星期 年 地址
rCALL WDS
ld r17,x ;寫秒 分 時 日 月 星期 年(R19中的數據)
rCALL WDS
cbi portd,7
cbi portd,6
sbi portd,7
ldi r17,0x8e ;控制寄存器un_en_WRITE
rCALL WDS
ldi r17,0x80 ;寫操作前WP=1
rCALL WDS
cbi portd,7
RET
同樣，下面給出了一個完整的讀取分的程序
ldi r18,0x83 ;讀分 命令
ldi r27,0x00 ;x H
ldi r26,19 ;x L 將取到的數據存儲到R19中。
READ_DS1302:
cbi portd,7
cbi portd,6
sbi portd,7
mov r17,r18 ;寫秒 分 時 日 月 星期 年 地址
rCALL WDS
rCALL RDS
st x,r17 ; 保存數據到R19
cbi portd,7
RET
整合寫和讀分的程序，改變R18的內容就可以實現“秒、分、時、日、月、星期、年”的讀寫，寫操作時只需改變R19的內容就可以將新的數據寫入，讀操作時直接讀取R19的內容即可。也可以通過此程序直接來對31個RAM進行數據讀取。
DS1302的充電功能
DS1302的涓流充電功能也是非常方便的，同時又是其非常重要的一個功能，所以簡單介紹一下其使用。其原理框圖如圖3。 |
