CPLD驅動數碼顯示電路

 1.1 顯示原理：
    八段數碼顯示管如圖1.1 所示，八段數碼管每一段為一發光二極體，共有a～g 以及小數點dp 八個發光二極體。將八段數碼管中的每個二極體的陰極並聯在一起，組成公共陰極端。這樣把共陰極管腳接地，此時哪個管腳輸入高電平，對應發光二極體就被點亮。
 
圖 1.1 八段數碼顯示管
    CL5461AS 數碼管管腳圖如圖1.2 所示，它將四個數碼顯示管的a～g 及小數點dp 管腳並聯在一起，作為數碼管數據輸入端；分別引出各個數碼管的陰極A1～A4。
 
圖1.2 CL5461AS 數碼管管腳圖
    只要在A1～A4 管腳上輪流加低電平其頻率大於40Hz，可實現四個數碼管同時被點亮的視覺效果。在點亮不同數碼管的同時輸入不同的數據，即可在數碼管上同時顯示四位不同的數字。例如：四個數碼管要顯示9876 數字。第一個數碼管A1 加低電平，其餘A2、A3、 A4高電平，同時數碼管輸入和9 對應的數據；然後第二個數碼管A2 加低電平，其餘A1、A3 、A4 高電平，同時數碼管輸入和8 對應的數據；然後第三個數碼管A3 加低電平，其餘A1、A2 、A4 高電平，同時數碼管輸入和7 對應的數據；然後第四個數碼管A4 加低電平，其餘A1、A2 、A3 高電平，同時數碼管輸入和6 對應的數據；周而復始重複上述過程，四個數碼管就顯示9876 數字。

1.2 驅動八位數碼管顯示電路框圖
    用CPLD 設計一個驅動八位數碼管顯示電路。八位數碼管管腳圖如圖1.2 所示。
    用兩個CL5461AS 數碼管接成一個八位數碼管顯示，將兩個CL5461AS 數碼管的a～g 及小數點dp 管腳並聯在一起，兩個CL5461AS 數碼管的陰極A1～A4 定義為Vss0、Vss1、Vss2、Vss3、Vss4、Vss5、Vss6、Vss7。
    用CPLD 設計一個驅動八位數碼管顯示電路的框圖如圖1.4 所示。
 
圖1.4 驅動八位數碼管顯示電路框圖
    時鐘脈衝計數器的輸出同時作為 3 線—8 線解碼器、八選一數據選擇器地址碼的輸入。
    時鐘脈衝計數器的輸出經過3 線—8 線解碼器解碼其輸出信號接到八位數碼管的陰極Vss0、Vss1、Vss2、Vss3、Vss4、Vss5、Vss6、Vss7 端。要顯示的數據信息Ａ～Ｈ中哪一個，通過八選一數據選擇器的地址碼來選擇，選擇出的數據信息經七段解碼器解碼接數碼管的a～g 管腳。這樣八個數碼管就可以輪流顯示八個數字，如果時鐘脈衝頻率合適，可實現八個數碼管同時被點亮的視覺效果。

1.3 模塊及模塊功能：
1.3.1 時鐘脈衝計數器模塊
    時鐘脈衝計數器模塊CN8 如圖1.5 所示。CN8 模塊輸入信號是時鐘脈衝clk，其頻率大於40Hz，每遇到一個時鐘脈衝clk 上升沿，內部累加器便加一，再把累加器所得結果以2進位數的形式輸出。要顯示八位數字，所以用3 位2 進位數作為輸出。輸出信號為cout[0..2]。
 
圖 1.5 時鐘脈衝計數器模塊CN8
library ieee;
use ieee.std_logic_1164.all;
use ieee.std_logic_unsigned.all;
entity cn8 is
port(clk:in std_logic;
cout:out std_logic_vector(2 downto 0));
end cn8;
architecture rtl of cn8 is
signal q: std_logic_vector(2 downto 0);
begin
process(clk)
begin
if (clk'event and clk='1' ) then
if (q=7) then
q<="000";
else
q<=q+1;
end if;
end if;
end process;
cout<=q;
end rtl;

1.3.2 3-8 線解碼器模塊
    3-8 線解碼器模塊DECODER3_8 如圖1.6 所示。DECODER3_8 模塊的輸入端是A[2..0]接收時鐘脈衝計數器CN8 模塊的輸出信號，經過解碼后輸出信號Q[7..0]分別接八個數碼管的陰極Vss7、Vss6、Vss5、Vss4、Vss3、Vss2、Vss1、Vss0，使對應的數碼管的陰極為低電平，對應的數碼管被點亮。要顯示八位數字，需要八個輸出端，所以做成3-8 線解碼器。
 
圖 1.6 3-8 線解碼器模塊DECODER3_8
library ieee;
use ieee.std_logic_1164.all;
entity decoder3_8 is
port(a:in std_logic_vector(2 downto 0);
q:out std_logic_vector(7 downto 0));
end decoder3_8;
architecture rtl of decoder3_8 is
begin
process(a)
begin
case a is
when "000"=>q<="11111110";
when "001"=>q<="11111101";
when "010"=>q<="11111011";
when "011"=>q<="11110111";
when "100"=>q<="11101111";
when "101"=>q<="11011111";
when "110"=>q<="10111111";
when others=>q<="01111111";
end case;
end process;
end rtl;

1.3.3 八選一數據選擇模塊
    八選一數據選擇模塊 SEL81 如圖1.7 所示。SEL81 模塊輸入信號一個是數據選擇器SEL81的地址碼SEL[2..0]，另一部分是數據信息A[3..0] ～H[3..0]。地址碼SEL[2..0]來自時鐘脈衝計數器CN8，由地址碼SEL[2..0]決定輸出哪個輸入數據。輸出信號是Q[3..0]。
 
圖 1.7 八選一數據選擇模塊SEL81
library ieee;
use ieee.std_logic_1164.all;
entity sel81 is
port(sel:in std_logic_vector(2 downto 0);
a,b,c,d,e,f,g,h:in std_logic_vector(3 downto 0);
q:out std_logic_vector(3 downto 0));
end sel81;
architecture rtl of sel81 is
begin
process(a,b,c,d,e,f,g,h,sel)
variable cout: std_logic_vector(3 downto 0);
begin
case (sel) is
when "000"=>cout:=a;
when "001"=>cout:=b;
when "010"=>cout:=c;
when "011"=>cout:=d;
when "100"=>cout:=e;
when "101"=>cout:=f;
when "110"=>cout:=g;
when others=>cout:=h;
end case;
q<=cout;
end process;
end rtl;

1.3.4 七段解碼器模塊
    七段解碼器模塊 DISP 如圖1.8 所示。DISP 模塊是七段解碼器，將輸入的4 位二進位數轉換為數碼顯示管所對應的數字。例如輸入為4 位二進位數0000 的時候，使數碼顯示管顯示0，則要七段解碼器輸出為0111111，即g 段為0，g 段發光二極體不亮，其他發光二極體被點亮，顯示效果為0。DISP 模塊輸入信號D[3..0]接到八選一數據選擇模塊的輸出信號Q[3..0]；七段解碼器輸出信號Q[6..0]接數碼管的a～g 管腳。
 
圖 1.8 七段解碼器模塊DISP
library ieee;
use ieee.std_logic_1164.all;
entity disp is
port(d:in std_logic_vector(3 downto 0);
q:out std_logic_vector(6 downto 0));
end disp;
architecture rtl of disp is
begin
process(d)
begin
case d is
when"0000"=>q<="0111111";
when"0001"=>q<="0000110";
when"0010"=>q<="1011011";
when"0011"=>q<="1001111";
when"0100"=>q<="1100110";
when"0101"=>q<="1101101";
when"0110"=>q<="1111101";
when"0111"=>q<="0100111";
when"1000"=>q<="1111111";
when others=>q<="1101111";
end case;
end process;
end rtl;

1.3.5 驅動八位數碼管顯示的整體電路
    將各個模塊連接起來構成整體電路圖如圖 1.9 所示，可以實現用CPLD 設計一個驅動八位數碼管顯示電路的功能。clk 是時鐘脈衝輸入信號，經過時鐘脈衝計數器CN8 模塊，將信號以3 位2 進位數的形式輸出，?出信號是COUT[2..0]。時鐘脈衝計數器CN8 的輸出同時作為3 線—8 線解碼器DECODER3_8 和八選一數據選擇器SEL81 地址碼SEL[2..0]的輸入。時鐘脈衝計數器CN8 的輸出經過3 線—8 線解碼器DECODER3_8 解碼其輸出信號Vss[7..0]接到八位數碼管的陰極Vss7、Vss6、Vss5、Vss4、Vss3、Vss2、Vss1、Vss0 端，決定點亮哪位數碼管。同時時鐘脈衝計數器CN8 模塊輸出的信號也進入數據選擇器SEL81 地址碼SEL[2..0]的輸入，進行輸出數據的選擇，其輸出是Q[3..0]。八選一數據選擇器SEL81 模塊的輸出是Q[3..0]再經過七段解碼器DISP 模塊，將其翻譯成可以用數碼顯示管的數據。七段解碼器DISP 模塊的輸出Q[6..0]分別經300 歐電阻接數碼顯示管的a～g 管腳。八選一數據選擇器模塊的輸入端，可根據具體需要進行設計。
 
圖 1.9 驅動八位數碼管顯示的整體電路