51單片機浮點運運算元程序庫

1: FSDT 功能:浮點數格式化
2: FADD 功能:浮點數加法
3: FSUB 功能:浮點數減法
4: FMUL 功能:浮點數乘法
5: FDIV 功能:浮點數除法
6: FCLR 功能:浮點數清零
7: FZER 功能:浮點數判零
8: FMOV 功能:浮點數傳送 
9: FPUS 功能:浮點數壓棧 
10: FPOP 功能:浮點數出棧
11: FCMP 功能:浮點數代數值比較不影響待比較操作數
12: FABS 功能:浮點絕對值函數
13: FSGN 功能:浮點符號函數
14: FINT 功能:浮點取整函數
15: FRCP 功能:浮點倒數函數
16: FSQU 功能:浮點數平方
17: FSQR 功能:浮點數開平方快速逼近演算法 
18: FPLN 功能:浮點數多項式計算
19: FLOG 功能:以10為底的浮點對數函數
20: FLN 功能:以e為底的浮點對數函數
21: FE10 功能:以10為底的浮點指數函數
22: FEXP 功能:以e為底的浮點指數函數
23: FE2 功能:以2為底的浮點指數函數
24: DTOF 功能:雙位元組十六進位定點數轉換成格式化浮點數 
25: FTOD 功能:格式化浮點數轉換成雙位元組定點數 
26: BTOF 功能:浮點BCD碼轉換成格式化浮點數
27: FTOB 功能:格式化浮點數轉換成浮點BCD碼
28: FCOS 功能:浮點餘弦函數
29: FSIN 功能:浮點正弦函數
30: FATN 功能:浮點反正切函數 
31: RTOD 功能:浮點弧度數轉換成浮點度數 
32: DTOR 功能:浮點度數轉換成浮點弧度數 

為便於讀者使用本程序庫,先將有關約定說明如下:
1.雙位元組定點操作數:用[R0]或[R1]來表示存放在由R0或R1指示的連續單元中的數據,地址小的單元存放高位元組｡如果[R0]=1234H,若(R0)=30H,則(30H)=12H,(31H)=34H｡
2.二進位浮點操作數:用三個位元組表示,第一個位元組的最高位為數符,其餘七位為階碼(補碼形式),第二位元組為尾數的高位元組,第三位元組為尾數的低位元組,尾數用雙位元組純小數(原碼)來表示｡當尾數的最高位為1時,便稱為規格化浮點數,簡稱操作數｡在程序說明中,也用[R0]或[R1]來表示R0或R1指示的浮點操作數,例如:當[R0]=-6.000時,則二進位浮點數表示為83C000H｡若(R0)=30H,則(30H)=83H,(31H)=0C0H,(32H)=00H｡
3.十進位浮點操作數:用三個位元組表示,第一個位元組的最高位為數符,其餘七位為階碼(二進位補碼形式),第二位元組為尾數的高位元組,第三位元組為尾數的低位元組,尾數用雙位元組BCD碼純小數(原碼)來表示｡當十進位數的絕對值大於1時,階碼就等於整數部分的位數,如 876.5 的階碼是03H,-876.5 的階碼是 83H;當十進位數的絕對值小於1時,階碼就等於 80H 減去小數點後面零的個數,例如 0.00382 的階碼是 7EH,-0.00382的階碼是 0FEH｡在程序說明中,用[R0]或[R1]來表示R0或R1指示的十進位浮點操作數｡例如有一個十進位浮點操作數存放在30H､31H､32H中,數值是 -0.07315,即-0.7315乘以10的-1次方,則(30H)=0FFH,31H=73H,(32H)=15H｡若用[R0]來指向它,則應使(R0)=30H｡
4.運算精度:單次定點運算精度為結果最低位的當量值;單次二進位浮點算術運算的精度優於十萬分之三;單次二進位浮點超越函數運算的精度優於萬分之一;BCD碼浮點數本身的精度比較低(萬分之一到千分之一),不宜作為運算的操作數,僅用於輸入或輸出時的數制轉換｡不管那種數據格式,隨著連續運算的次數增加,精度都會下降｡
5.工作區:數據工作區固定在A､B､R2~R7,數符或標誌工作區固定在PSW和23H單元(位1CH~1FH)｡在浮點系統中,R2､R3､R4和位1FH為第一工作區,R5､R6､R7和位1EH為第二工作區｡用戶只要不在工作區中存放無關的或非消耗性的信息,程序就具有較好的透明性｡
6.子程序調用範例:由於本程序庫特別注意了各子程序介面的相容性,很容易採用積木方式(或流水線方式)完成一個公式的計算｡以浮點運算為例:
計算 y = Ln √ | Sin (ab/c+d) |
已知:a=-123.4;b=0.7577;c=56.34;d=1.276; 它們分別存放在30H､33H､36H､39H開始的連續三個單元中｡用BCD碼浮點數表示時,分別為a=831234H;b=007577H;c=025634H;d=011276H｡
求解過程:通過調用BTOF子程序,將各變數轉換成二進位浮點操作數,再進行各
種運算,最後調用FTOB子程序,還原成十進位形式,供輸出使用｡程序如下:

TEST: MOV R0,#39H ;指向BCD碼浮點操作數d
LCALL BTOF ;將其轉換成二進位浮點操作數
MOV R0,#36H ;指向BCD碼浮點操作數c
LCALL BTOF ;將其轉換成二進位浮點操作數
MOV R0,#33H ;指向BCD碼浮點操作數b
LCALL BTOF ;將其轉換成二進位浮點操作數
MOV R0,#30H ;指向BCD碼浮點操作數a
LCALL BTOF ;將其轉換成二進位浮點操作數
MOV R1,#33H ;指向二進位浮點操作數b
LCALL FMUL ;進行浮點乘法運算
MOV R1,#36H ;指向二進位浮點操作數c
LCALL FDIV ;進行浮點除法運算
MOV R1,#39H ;指向二進位浮點操作數d
LCALL FADD ;進行浮點加法運算
LCALL FSIN ;進行浮點正弦運算
LCALL FABS ;進行浮點絕對值運算
LCALL FSQR ;進行浮點開平方運算
LCALL FLN ;進行浮點對數運算
LCALL FTOB ;將結果轉換成BCD碼浮點數
STOP: LJMP STOP
END

運行結果,[R0]=804915H,即y=-0.4915,比較精確的結果應該是-0.491437｡

(1) 標號: FSDT 功能:浮點數格式化
入口條件:待格式化浮點操作數在[R0]中｡
出口信息:已格式化浮點操作數仍在[R0]中｡
影響資源:PSW､A､R2､R3､R4､位1FH 堆棧需求: 6位元組
FSDT: LCALL MVR0 ;將待格式化操作數傳送到第一工作區中
LCALL RLN ;通過左規完成格式化
LJMP MOV0 ;將已格式化浮點操作數傳回到[R0]中

(2) 標號: FADD 功能:浮點數加法
入口條件:被加數在[R0]中,加數在[R1]中｡
出口信息:OV=0時,和仍在[R0]中,OV=1時,溢出｡
影響資源:PSW､A､B､R2~R7､位1EH､1FH 堆棧需求: 6位元組
FADD: CLR F0 ;設立加法標誌
SJMP AS ;計算代數和

(3) 標號: FSUB 功能:浮點數減法
入口條件:被減數在[R0]中,減數在[R1]中｡
出口信息:OV=0時,差仍在[R0]中,OV=1時,溢出｡
影響資源:PSW､A､B､R2~R7､位1EH､1FH 堆棧需求:6位元組
FSUB: SETB F0 ;設立減法標誌
AS: LCALL MVR1 ;計算代數和｡先將[R1]傳送到第二工作區
MOV C,F0 ;用加減標誌來校正第二操作數的有效符號
RRC A
XRL A,@R1
MOV C,ACC.7
ASN: MOV 1EH,C ;將第二操作數的有效符號存入位1EH中
XRL A,@R0 ;與第一操作數的符號比較
RLC A
MOV F0,C ;保存比較結果
LCALL MVR0 ;將[R0]傳送到第一工作區中
LCALL AS1 ;在工作寄存器中完成代數運算
MOV0: INC R0 ;將結果傳回到[R0]中的子程序入口
INC R0
MOV A,R4 ;傳回尾數的低位元組
MOV @R0,A
DEC R0
MOV A,R3 ;傳回尾數的高位元組
MOV @R0,A
DEC R0
MOV A,R2 ;取結果的階碼
MOV C,1FH ;取結果的數符
MOV ACC.7,C ;拼入階碼中
MOV @R0,A
CLR ACC.7 ;不考慮數符
CLR OV ;清除溢出標誌
CJNE A,#3FH,MV01;階碼是否上溢?
SETB OV ;設立溢出標誌
MV01: MOV A,@R0 ;取出帶數符的階碼
RET
MVR0: MOV A,@R0 ;將[R0]傳送到第一工作區中的子程序
MOV C,ACC.7 ;將數符保存在位1FH中
MOV 1FH,C
MOV C,ACC.6 ;將階碼擴充為8bit補碼
MOV ACC.7,C
MOV R2,A ;存放在R2中
INC R0
MOV A,@R0 ;將尾數高位元組存放在R3中
MOV R3,A
INC R0
MOV A,@R0 ;將尾數低位元組存放在R4中
MOV R4,A
DEC R0 ;恢複數據指針
DEC R0
RET
MVR1: MOV A,@R1 ;將[R1]傳送到第二工作區中的子程序
MOV C,ACC.7 ;將數符保存在位1EH中
MOV 1EH,C
MOV C,ACC.6 ;將階碼擴充為8bit補碼
MOV ACC.7,C
MOV R5,A ;存放在R5中
INC R1
MOV A,@R1 ;將尾數高位元組存放在R6中
MOV R6,A
INC R1
MOV A,@R1 ;將尾數低位元組存放在R7中
MOV R7,A
DEC R1 ;恢複數據指針
DEC R1
RET
AS1: MOV A,R6 ;讀取第二操作數尾數高位元組
ORL A,R7
JZ AS2 ;第二操作數為零,不必運算
MOV A,R3 ;讀取第一操作數尾數高位元組
ORL A,R4
JNZ EQ1
MOV A,R6 ;第一操作數為零,結果以第二操作數為準
MOV R3,A
MOV A,R7
MOV R4,A
MOV A,R5
MOV R2,A
MOV C,1EH
MOV 1FH,C
AS2: RET
EQ1: MOV A,R2 ;對階,比較兩個操作數的階碼
XRL A,R5
JZ AS4 ;階碼相同,對階結束
JB ACC.7,EQ3;階符互異
MOV A,R2 ;階符相同,比較大小
CLR C
SUBB A,R5
JC EQ4
EQ2: CLR C ;第二操作數右規一次
MOV A,R6 ;尾數縮小一半
RRC A
MOV R6,A
MOV A,R7
RRC A
MOV R7,A
INC R5 ;階碼加一
ORL A,R6 ;尾數為零否?
JNZ EQ1 ;尾數不為零,繼續對階
MOV A,R2 ;尾數為零,提前結束對階
MOV R5,A
SJMP AS4
EQ3: MOV A,R2 ;判斷第一操作數階符
JNB ACC.7,EQ2;如為正,右規第二操作數
EQ4: CLR C
LCALL RR1 ;第一操作數右規一次
ORL A,R3 ;尾數為零否?
JNZ EQ1 ;不為零,繼續對階
MOV A,R5 ;尾數為零,提前結束對階
MOV R2,A
AS4: JB F0,AS5 ;尾數加減判斷
MOV A,R4 ;尾數相加
ADD A,R7
MOV R4,A
MOV A,R3
ADDC A,R6
MOV R3,A
JNC AS2
LJMP RR1 ;有進位,右規一次
AS5: CLR C ;比較絕對值大小
MOV A,R4
SUBB A,R7
MOV B,A
MOV A,R3
SUBB A,R6
JC AS6
MOV R4,B ;第一尾數減第二尾數
MOV R3,A
LJMP RLN ;結果規格化
AS6: CPL 1FH ;結果的符號與第一操作數相反
CLR C ;結果的絕對值為第二尾數減第一尾數
MOV A,R7
SUBB A,R4
MOV R4,A
MOV A,R6
SUBB A,R3
MOV R3,A
RLN: MOV A,R3 ;浮點數規格化
ORL A,R4 ;尾數為零否?
JNZ RLN1
MOV R2,#0C1H;階碼取最小值
RET
RLN1: MOV A,R3
JB ACC.7,RLN2;尾數最高位為一否?
CLR C ;不為一,左規一次
LCALL RL1
SJMP RLN ;繼續判斷
RLN2: CLR OV ;規格化結束
RET
RL1: MOV A,R4 ;第一操作數左規一次
RLC A ;尾數擴大一倍
MOV R4,A
MOV A,R3
RLC A
MOV R3,A
DEC R2 ;階碼減一
CJNE R2,#0C0H,RL1E;階碼下溢否?
CLR A
MOV R3,A ;階碼下溢,操作數以零計
MOV R4,A
MOV R2,#0C1H
RL1E: CLR OV
RET
RR1: MOV A,R3 ;第一操作數右規一次
RRC A ;尾數縮小一半
MOV R3,A
MOV A,R4
RRC A
MOV R4,A
INC R2 ;階碼加一
CLR OV ;清溢出標誌
CJNE R2,#40H,RR1E;階碼上溢否?
MOV R2,#3FH ;階碼溢出
SETB OV
RR1E: RET

(4) 標號:FMUL 功能:浮點數乘法
入口條件:被乘數在[R0]中,乘數在[R1]中｡
出口信息:OV=0時,積仍在[R0]中,OV=1時,溢出｡
影響資源:PSW､A､B､R2~R7､位1EH､1FH 堆棧需求:6位元組
FMUL: LCALL MVR0 ;將[R0]傳送到第一工作區中
MOV A,@R0
XRL A,@R1 ;比較兩個操作數的符號
RLC A
MOV 1FH,C ;保存積的符號
LCALL MUL0 ;計算積的絕對值
LJMP MOV0 ;將結果傳回到[R0]中
MUL0: LCALL MVR1 ;將[R1]傳送到第二工作區中
MUL1: MOV A,R3 ;第一尾數為零否?
ORL A,R4
JZ MUL6
MOV A,R6 ;第二尾數為零否?
ORL A,R7
JZ MUL5
MOV A,R7 ;計算R3R4×R6R7-→R3R4
MOV B,R4
MUL AB
MOV A,B
XCH A,R7
MOV B,R3
MUL AB
ADD A,R7
MOV R7,A
CLR A
ADDC A,B
XCH A,R4
MOV B,R6
MUL AB
ADD A,R7
MOV R7,A
MOV A,B
ADDC A,R4
MOV R4,A
CLR A
RLC A
XCH A,R3
MOV B,R6
MUL AB
ADD A,R4
MOV R4,A
MOV A,B
ADDC A,R3
MOV R3,A
JB ACC.7,MUL2;積為規格化數否?
MOV A,R7 ;左規一次
RLC A
MOV R7,A
LCALL RL1
MUL2: MOV A,R7
JNB ACC.7,MUL3
INC R4
MOV A,R4
JNZ MUL3
INC R3
MOV A,R3
JNZ MUL3
MOV R3,#80H
INC R2
MUL3: MOV A,R2 ;求積的階碼
ADD A,R5
MD: MOV R2,A ;階碼溢出判斷
JB ACC.7,MUL4
JNB ACC.6,MUL6
MOV R2,#3FH ;階碼上溢,設立標誌
SETB OV
RET
MUL4: JB ACC.6,MUL6
MUL5: CLR A ;結果清零(因子為零或階碼下溢)
MOV R3,A
MOV R4,A
MOV R2,#41H
MUL6: CLR OV
RET

(5) 標號: FDIV 功能:浮點數除法
入口條件:被除數在[R0]中,除數在[R1]中｡
出口信息:OV=0時,商仍在[R0]中,OV=1時,溢出｡
影響資源:PSW､A､B､R2~R7､位1EH､1FH 堆棧需求: 5位元組
FDIV: INC R0
MOV A,@R0
INC R0
ORL A,@R0
DEC R0
DEC R0
JNZ DIV1
MOV @R0,#41H;被除數為零,不必運算
CLR OV
RET
DIV1: INC R1
MOV A,@R1
INC R1
ORL A,@R1
DEC R1
DEC R1
JNZ DIV2
SETB OV ;除數為零,溢出
RET
DIV2: LCALL MVR0 ;將[R0]傳送到第一工作區中
MOV A,@R0
XRL A,@R1 ;比較兩個操作數的符號
RLC A
MOV 1FH,C ;保存結果的符號
LCALL MVR1 ;將[R1]傳送到第二工作區中
LCALL DIV3 ;調用工作區浮點除法
LJMP MOV0 ;回傳結果
DIV3: CLR C ;比較尾數的大小
MOV A,R4
SUBB A,R7
MOV A,R3
SUBB A,R6
JC DIV4
LCALL RR1 ;被除數右規一次
SJMP DIV3
DIV4: CLR A ;借用R0R1R2作工作寄存器
XCH A,R0 ;清零並保護之
PUSH ACC
CLR A
XCH A,R1
PUSH ACC
MOV A,R2
PUSH ACC
MOV B,#10H ;除法運算,R3R4/R6R7-→R0R1
DIV5: CLR C
MOV A,R1
RLC A
MOV R1,A
MOV A,R0
RLC A
MOV R0,A
MOV A,R4
RLC A
MOV R4,A
XCH A,R3
RLC A
XCH A,R3
MOV F0,C
CLR C
SUBB A,R7
MOV R2,A
MOV A,R3
SUBB A,R6
ANL C,/F0
JC DIV6
MOV R3,A
MOV A,R2
MOV R4,A
INC R1
DIV6: DJNZ B,DIV5
MOV A,R6 ;四捨五入
CLR C
RRC A
SUBB A,R3
CLR A
ADDC A,R1 ;將結果存回R3R4
MOV R4,A
CLR A
ADDC A,R0
MOV R3,A
POP ACC ;恢復R0R1R2
MOV R2,A
POP ACC
MOV R1,A
POP ACC
MOV R0,A
MOV A,R2 ;計算商的階碼
CLR C
SUBB A,R5
LCALL MD ;階碼檢驗
LJMP RLN ;規格化

(6) 標號: FCLR 功能:浮點數清零
入口條件:操作數在[R0]中｡
出口信息:操作數被清零｡
影響資源:A 堆棧需求: 2位元組
FCLR: INC R0
INC R0
CLR A
MOV @R0,A
DEC R0
MOV @R0,A
DEC R0
MOV @R0,#41H
RET

(7) 標號: FZER 功能:浮點數判零
入口條件:操作數在[R0]中｡
出口信息:若累加器A為零,則操作數[R0]為零,否則不為零｡
影響資源:A 堆棧需求: 2位元組
FZER: INC R0
INC R0
MOV A,@R0
DEC R0
ORL A,@R0
DEC R0
JNZ ZERO
MOV @R0,#41H
ZERO: RET

(8) 標號: FMOV 功能:浮點數傳送
入口條件:源操作數在[R1]中,目標地址為[R0]｡
出口信息:[R0]=[R1],[R1]不變｡
影響資源:A 堆棧需求: 2位元組
FMOV: INC R0
INC R0
INC R1
INC R1
MOV A,@R1
MOV @R0,A
DEC R0
DEC R1
MOV A,@R1
MOV @R0,A
DEC R0
DEC R1
MOV A,@R1
MOV @R0,A
RET

(9) 標號: FPUS 功能:浮點數壓棧
入口條件:操作數在[R0]中｡
出口信息:操作數壓入棧頂｡
影響資源:A､R2､R3 堆棧需求: 5位元組
FPUS: POP ACC ;將返回地址保存在R2R3中
MOV R2,A
POP ACC
MOV R3,A
MOV A,@R0 ;將操作數壓入堆棧
PUSH ACC
INC R0
MOV A,@R0
PUSH ACC
INC R0
MOV A,@R0
PUSH ACC
DEC R0
DEC R0
MOV A,R3 ;將返回地址壓入堆棧
PUSH ACC
MOV A,R2
PUSH ACC
RET ;返回主程序

(10) 標號: FPOP 功能:浮點數出棧
入口條件:操作數處於棧頂｡
出口信息:操作數彈至[R0]中｡
影響資源:A､R2､R3 堆棧需求: 2位元組
FPOP: POP ACC ;將返回地址保存在R2R3中
MOV R2,A
POP ACC
MOV R3,A
INC R0
INC R0
POP ACC ;將操作數彈出堆棧,傳送到[R0]中
MOV @R0,A
DEC R0
POP ACC
MOV @R0,A
DEC R0
POP ACC
MOV @R0,A
MOV A,R3 ;將返回地址壓入堆棧
PUSH ACC
MOV A,R2
PUSH ACC
RET ;返回主程序

(11) 標號: FCMP 功能:浮點數代數值比較(不影響待比較操作數)
入口條件:待比較操作數分別在[R0]和[R1]中｡
出口信息:若CY=1,則[R0] < [R1],若CY=0且A=0則 [R0] = [R1],否則[R0] > [R1]｡
影響資源:A､B､PSW 堆棧需求: 2位元組
FCMP: MOV A,@R0 ;數符比較
XRL A,@R1
JNB ACC.7,CMP2
MOV A,@R0 ;兩數異號,以[R0]數符為準
RLC A
MOV A,#0FFH
RET
CMP2: MOV A,@R1 ;兩數同號,準備比較階碼
MOV C,ACC.6
MOV ACC.7,C
MOV B,A
MOV A,@R0
MOV C,ACC.7
MOV F0,C ;保存[R0]的數符
MOV C,ACC.6
MOV ACC.7,C
CLR C ;比較階碼
SUBB A,B
JZ CMP6
RLC A ;取階碼之差的符號
JNB F0,CMP5
CPL C ;[R0]為負時,結果取反
CMP5: MOV A,#0FFH ;兩數不相等
RET
CMP6: INC R0 ;階碼相同時,準備比較尾數
INC R0
INC R1
INC R1
CLR C
MOV A,@R0
SUBB A,@R1
MOV B,A ;保存部分差
DEC R0
DEC R1
MOV A,@R0
SUBB A,@R1
DEC R0
DEC R1
ORL A,B ;生成是否相等信息
JZ CMP7
JNB F0,CMP7
CPL C ;[R0]為負時,結果取反
CMP7: RET

(12) 標號: FABS 功能:浮點絕對值函數
入口條件:操作數在[R0]中｡
出口信息:結果仍在[R0]中｡
影響資源:A 堆棧需求: 2位元組
FABS: MOV A,@R0 ;讀取操作數的階碼
CLR ACC.7 ;清除數符
MOV @R0,A ;回傳階碼
RET

(13) 標號: FSGN 功能:浮點符號函數
入口條件:操作數在[R0]中｡
出口信息:累加器 A=1 時為正數,A=0FFH時為負數,A=0 時為零｡
影響資源:PSW､A 堆棧需求: 2位元組
FSGN: INC R0 ;讀尾數
MOV A,@R0
INC R0
ORL A,@R0
DEC R0
DEC R0
JNZ SGN
RET ;尾數為零,結束
SGN: MOV A,@R0 ;讀取操作數的階碼
RLC A ;取數符
MOV A,#1 ;按正數初始化
JNC SGN1 ;是正數,結束
MOV A,#0FFH ;是負數,改變標誌
SGN1: RET

(14) 標號: FINT 功能:浮點取整函數
入口條件:操作數在[R0]中｡
出口信息:結果仍在[R0]中｡
影響資源:PSW､A､R2､R3､R4､位1FH 堆棧需求: 6位元組
FINT: LCALL MVR0 ;將[R0]傳送到第一工作區中
LCALL INT ;在工作寄存器中完成取整運算
LJMP MOV0 ;將結果傳回到[R0]中
INT: MOV A,R3
ORL A,R4
JNZ INTA
CLR 1FH ;尾數為零,階碼也清零,結束取整
MOV R2,#41H
RET
INTA: MOV A,R2
JZ INTB ;階碼為零否?
JB ACC.7,INTB;階符為負否?
CLR C
SUBB A,#10H ;階碼小於16否?
JC INTD
RET ;階碼大於16,已經是整數
INTB: CLR A ;絕對值小於一,取整后正數為零,負數為負一
MOV R4,A
MOV C,1FH
RRC A
MOV R3,A
RL A
MOV R2,A
JNZ INTC
MOV R2,#41H
INTC: RET
INTD: CLR F0 ;舍尾標誌初始化
INTE: CLR C
LCALL RR1 ;右規一次
ORL C,F0 ;記憶舍尾情況
MOV F0,C
CJNE R2,#10H,INTE;階碼達到16(尾數完全為整數)否?
JNB F0,INTF ;捨去部分為零否?
JNB 1FH,INTF;操作數為正數否?
INC R4 ;對於帶小數的負數,向下取整
MOV A,R4
JNZ INTF
INC R3
INTF: LJMP RLN ;將結果規格化

(15) 標號: FRCP 功能:浮點倒數函數
入口條件:操作數在[R0]中｡
出口信息:OV=0時,結果仍在[R0]中,OV=1時,溢出｡
影響資源:PSW､A､B､R2~R7､位1EH､1FH 堆棧需求: 5位元組
FRCP: MOV A,@R0
MOV C,ACC.7
MOV 1FH,C ;保存數符
MOV C,ACC.6 ;絕對值傳送到第二工作區
MOV ACC.7,C
MOV R5,A
INC R0
MOV A,@R0
MOV R6,A
INC R0
MOV A,@R0
MOV R7,A
DEC R0
DEC R0
ORL A,R6
JNZ RCP
SETB OV ;零不能求倒數,設立溢出標誌
RET
RCP: MOV A,R6
JB ACC.7,RCP2;操作數格式化否?
CLR C ;格式化之
MOV A,R7
RLC A
MOV R7,A
MOV A,R6
RLC A
MOV R6,A
DEC R5
SJMP RCP
RCP2: MOV R2,#1 ;將數值1.00傳送到第一工作區
MOV R3,#80H
MOV R4,#0
LCALL DIV3 ;調用工作區浮點除法,求得倒數
LJMP MOV0 ;回傳結果

(16) 標號: FSQU 功能:浮點數平方
入口條件:操作數在[R0]中｡
出口信息:OV=0時,平方值仍然在[R0]中,OV=1時溢出｡
影響資源:PSW､A､B､R2~R7､位1EH､1FH 堆棧需求: 9位元組
FSQU: MOV A,R0 ;將操作數
XCH A,R1 ;同時作為乘數
PUSH ACC ;保存R1指針
LCALL FMUL ;進行乘法運算
POP ACC
MOV R1,A ;恢復R1指針
RET

(17) 標號: FSQR 功能:浮點數開平方(快速逼近演算法)
入口條件:操作數在[R0]中｡
出口信息:OV=0時,平方根仍在[R0]中,OV=1時,負數開平方出錯｡
影響資源:PSW､A､B､R2~R7 堆棧需求: 2位元組
FSQR: MOV A,@R0
JNB ACC.7,SQR
SETB OV ;負數開平方,出錯
RET
SQR: INC R0
INC R0
MOV A,@R0
DEC R0
ORL A,@R0
DEC R0
JNZ SQ
MOV @R0,#41H;尾數為零,不必運算
CLR OV
RET
SQ: MOV A,@R0
MOV C,ACC.6 ;將階碼擴展成8bit補碼
MOV ACC.7,C
INC A ;加一
CLR C
RRC A ;除二
MOV @R0,A ;得到平方根的階碼,回存之
INC R0 ;指向被開方數尾數的高位元組
JC SQR0 ;原被開方數的階碼是奇數嗎?
MOV A,@R0 ;是奇數,尾數右規一次
RRC A
MOV @R0,A
INC R0
MOV A,@R0
RRC A
MOV @R0,A
DEC R0
SQR0: MOV A,@R0
JZ SQR9 ;尾數為零,不必運算
MOV R2,A ;將尾數傳送到R2R3中
INC R0
MOV A,@R0
MOV R3,A
MOV A,R2 ;快速開方,參閱定點子程序說明
ADD A,#57H
JC SQR2
ADD A,#45H
JC SQR1
ADD A,#24H
MOV B,#0E3H
MOV R4,#80H
SJMP SQR3
SQR1: MOV B,#0B2H
MOV R4,#0A0H
SJMP SQR3
SQR2: MOV B,#8DH
MOV R4,#0D0H
SQR3: MUL AB
MOV A,B
ADD A,R4
MOV R4,A
MOV B,A
MUL AB
XCH A,R3
CLR C
SUBB A,R3
MOV R3,A
MOV A,B
XCH A,R2
SUBB A,R2
MOV R2,A
SQR4: SETB C
MOV A,R4
RLC A
MOV R6,A
CLR A
RLC A
MOV R5,A
MOV A,R3
SUBB A,R6
MOV B,A
MOV A,R2
SUBB A,R5
JC SQR5
INC R4
MOV R2,A
MOV R3,B
SJMP SQR4
SQR5: MOV A,R4
XCH A,R2
RRC A
MOV F0,C
MOV A,R3
MOV R5,A
MOV R4,#8
SQR6: CLR C
MOV A,R3
RLC A
MOV R3,A
CLR C
MOV A,R5
SUBB A,R2
JB F0,SQR7
JC SQR8
SQR7: MOV R5,A
INC R3
SQR8: CLR C
MOV A,R5
RLC A
MOV R5,A
MOV F0,C
DJNZ R4,SQR6
MOV A,R3 ;將平方根的尾數回傳到[R0]中
MOV @R0,A
DEC R0
MOV A,R2
MOV @R0,A
SQR9: DEC R0 ;數據指針回歸原位
CLR OV ;開方結果有效
RET

(18) 標號: FPLN 功能:浮點數多項式計算
入口條件:自變數在[R0]中,多項式係數在調用指令之後,以40H結束｡
出口信息:OV=0時,結果仍在[R0]中,OV=1時,溢出｡
影響資源:DPTR､PSW､A､B､R2~R7､位1EH､1FH 堆棧需求: 4位元組
FPLN: POP DPH ;取出多項式係數存放地址
POP DPL
XCH A,R0 ;R0､R1交換角色,自變數在[R1]中
XCH A,R1
XCH A,R0
CLR A ;清第一工作區
MOV R2,A
MOV R3,A
MOV R4,A
CLR 1FH
PLN1: CLR A ;讀取一個係數,並裝入第二工作區
MOVC A,@A+DPTR
MOV C,ACC.7
MOV 1EH,C
MOV C,ACC.6
MOV ACC.7,C
MOV R5,A
INC DPTR
CLR A
MOVC A,@A+DPTR
MOV R6,A
INC DPTR
CLR A
MOVC A,@A+DPTR
MOV R7,A
INC DPTR ;指向下一個係數
MOV C,1EH ;比較兩個數符
RRC A
XRL A,23H
RLC A
MOV F0,C ;保存比較結果
LCALL AS1 ;進行代數加法運算
CLR A ;讀取下一個係數的第一個位元組
MOVC A,@A+DPTR
CJNE A,#40H,PLN2;是結束標誌嗎?
XCH A,R0 ;運算結束,恢復R0､R1原來的角色
XCH A,R1
XCH A,R0
LCALL MOV0 ;將結果回傳到[R0]中
CLR A
INC DPTR
JMP @A+DPTR ;返回主程序
PLN2: MOV A,@R1 ;比較自變數和中間結果的符號
XRL A,23H
RLC A
MOV 1FH,C ;保存比較結果
LCALL MUL0 ;進行乘法運算
SJMP PLN1 ;繼續下一項運算

(19) 標號: FLOG 功能:以10為底的浮點對數函數
入口條件:操作數在[R0]中｡
出口信息:OV=0時,結果仍在[R0]中,OV=1時,負數或零求對數出錯｡
影響資源:DPTR､PSW､A､B､R2~R7､位1EH､1FH 堆棧需求:9位元組
FLOG: LCALL FLN ;先以e為底求對數
JNB OV,LOG
RET ;如溢出則停止計算
LOG: MOV R5,#0FFH;係數0.43430(1/Ln10)
MOV R6,#0DEH
MOV R7,#5CH
LCALL MUL1 ;通過相乘來換底
LJMP MOV0 ;傳回結果

(20) 標號: FLN 功能:以e為底的浮點對數函數
入口條件:操作數在[R0]中｡
出口信息:OV=0時,結果仍在[R0]中,OV=1時,負數或零求對數出錯｡
影響資源:DPTR､PSW､A､B､R2~R7､位1EH､1FH 堆棧需求: 7位元組
FLN: LCALL MVR0 ;將[R0]傳送到第一工作區
JB 1FH,LNOV;負數或零求對數,出錯
MOV A,R3
ORL A,R4
JNZ LN0
LNOV: SETB OV
RET
LN0: CLR C
LCALL RL1 ;左規一次
CLR A
XCH A,R2 ;保存原階碼,清零工作區的階碼
PUSH ACC
LCALL RLN ;規格化
LCALL MOV0 ;回傳
LCALL FPLN ;用多項式計算尾數的對數
DB 7BH,0F4H,30H;0.029808
DB 0FEH,85H,13H;-0.12996
DB 7FH,91H,51H;0.28382
DB 0FFH,0FAH,0BAH;-0.4897
DB 0,0FFH,0CAH;0.99918
DB 70H,0C0H,0;1.1442×10-5
DB 40H ;結束
POP ACC ;取出原階碼
JNZ LN1
RET ;如為零,則結束
LN1: CLR 1EH ;清第二區數符
MOV C,ACC.7
MOV F0,C ;保存階符
JNC LN2
CPL A ;當階碼為負時,求其絕對值
INC A
LN2: MOV R2,A ;階碼的絕對值乘以0.69315
MOV B,#72H
MUL AB
XCH A,R2
MOV R7,B
MOV B,#0B1H
MUL AB
ADD A,R7
MOV R7,A ;乘積的尾數在R6R7R2中
CLR A
ADDC A,B
MOV R6,A
MOV R5,#8 ;乘積的階碼初始化(整數部分為一位元組)
LN3: JB ACC.7,LN4;乘積格式化
MOV A,R2
RLC A
MOV R2,A
MOV A,R7
RLC A
MOV R7,A
MOV A,R6
RLC A
MOV R6,A
DEC R5
SJMP LN3
LN4: MOV C,F0 ;取出階符,作為乘積的數符
MOV ACC.7,C
LJMP ASN ;與尾數的對數合併,得原操作數的對數

(21) 標號: FE10 功能:以10為底的浮點指數函數
入口條件:操作數在[R0]中｡
出口信息:OV=0時,結果仍在[R0]中,OV=1時,溢出｡
影響資源:DPTR､PSW､A､B､R2~R7､位1EH､1FH 堆棧需求:6位元組
FE10: MOV R5,#2 ;加權係數為3.3219(Log210)
MOV R6,#0D4H
MOV R7,#9AH
SJMP EXP ;先進行加權運算,后以2為底統一求冪

(22) 標號: FEXP 功能:以e為底的浮點指數函數
入口條件:操作數在[R0]中｡
出口信息:OV=0時,結果仍在[R0]中,OV=1時,溢出｡
影響資源:DPTR､PSW､A､B､R2~R7､位1EH､1FH 堆棧需求:6位元組
FEXP: MOV R5,#1 ;加權係數為1.44272(Lng2e)
MOV R6,#0B8H
MOV R7,#0ABH
EXP: CLR 1EH ;加權係數為正數
LCALL MVR0 ;將[R0]傳送到第一工作區
LCALL MUL1 ;進行加權運算
SJMP E20 ;以2為底統一求冪

(23) 標號: FE2 功能:以2為底的浮點指數函數
入口條件:操作數在[R0]中｡
出口信息:OV=0時,結果仍在[R0]中,OV=1時,溢出｡
影響資源:DPTR､PSW､A､B､R2~R7､位1EH､1FH 堆棧需求:6位元組
FE2: LCALL MVR0 ;將[R0]傳送到第一工作區
E20: MOV A,R3
ORL A,R4
JZ EXP1 ;尾數為零
MOV A,R2
JB ACC.7,EXP2;階符為負?
SETB C
SUBB A,#6 ;階碼大於6否?
JC EXP2
JB 1FH,EXP0;數符為負否?
MOV @R0,#3FH;正指數過大,冪溢出
INC R0
MOV @R0,#0FFH
INC R0
MOV @R0,#0FFH
DEC R0
DEC R0
SETB OV
RET
EXP0: MOV @R0,#41H;負指數過大,冪下溢,清零處理
CLR A
INC R0
MOV @R0,A
INC R0
MOV @R0,A
DEC R0
DEC R0
CLR OV
RET
EXP1: MOV @R0,#1 ;指數為零,冪為1.00
INC R0
MOV @R0,#80H
INC R0
MOV @R0,#0
DEC R0
DEC R0
CLR OV
RET
EXP2: MOV A,R2 ;將指數複製到第二工作區
MOV R5,A
MOV A,R3
MOV R6,A
MOV A,R4
MOV R7,A
MOV C,1FH
MOV 1EH,C
LCALL INT ;對第一區取整
MOV A,R3
JZ EXP4
EXP3: CLR C ;使尾數高位元組R3對應一個位元組整數
RRC A
INC R2
CJNE R2,#8,EXP3
EXP4: MOV R3,A
JNB 1FH,EXP5
CPL A ;並用補碼錶示
INC A
EXP5: PUSH ACC ;暫時保存之
LCALL RLN ;重新規格化
CPL 1FH
SETB F0
LCALL AS1 ;求指數的小數部分
LCALL MOV0 ;回傳指數的小數部分
LCALL FPLN ;通過多項式計算指數的小數部分的冪
DB 77H,0B1H,0C9H;1.3564×10-3
DB 7AH,0A1H,68H;9.8514×10-3
DB 7CH,0E3H,4FH;0.055495
DB 7EH,0F5H,0E7H;0.24014
DB 0,0B1H,72H;0.69315
DB 1,80H,0 ;1.00000
DB 40H ;結束
POP ACC ;取出指數的整數部分
ADD A,R2 ;按補碼加到冪的階碼上
MOV R2,A
CLR 1FH ;冪的符號為正
LJMP MOV0 ;將冪傳回[R0]中

(24)標號: DTOF 功能:雙位元組十六進位定點數轉換成格式化浮點數
入口條件:雙位元組定點數的絕對值在[R0]中,數符在位1FH中,整數部分的位數在A中｡
出口信息:轉換成格式化浮點數在[R0]中(三位元組)｡
影響資源:PSW､A､R2､R3､R4､位1FH 堆棧需求: 6位元組
DTOF: MOV R2,A ;按整數的位數初始化階碼
MOV A,@R0 ;將定點數作尾數
MOV R3,A
INC R0
MOV A,@R0
MOV R4,A
DEC R0
LCALL RLN ;進行規格化
LJMP MOV0 ;傳送結果到[R0]中

(25) 標號: FTOD 功能:格式化浮點數轉換成雙位元組定點數
入口條件:格式化浮點操作數在[R0]中｡
出口信息:OV=1時溢出,OV=0時轉換成功:定點數的絕對值在[R0]中(雙位元組),數符
在位1FH中,F0=1 時為整數,CY=1時為一位元組整數一位元組小數,否則為純小數｡
影響資源:PSW､A､B､R2､R3､R4､位1FH 堆棧需求: 6位元組
FTOD: LCALL MVR0 ;將[R0]傳送到第一工作區
MOV A,R2
JZ FTD4 ;階碼為零,純小數
JB ACC.7,FTD4;階碼為負,純小數
SETB C
SUBB A,#10H
JC FTD1
SETB OV ;階碼大於16,溢出
RET
FTD1: SETB C
MOV A,R2
SUBB A,#8 ;階碼大於8否?
JC FTD3
FTD2: MOV B,#10H ;階碼大於8,按雙位元組整數轉換
LCALL FTD8
SETB F0 ;設立雙位元組整數標誌
CLR C
CLR OV
RET
FTD3: MOV B,#8 ;按一位元組整數一位元組小數轉換
LCALL FTD8
SETB C ;設立一位元組整數一位元組小數標誌
CLR F0
CLR OV
RET
FTD4: MOV B,#0 ;按純小數轉換
LCALL FTD8
CLR OV ;設立純小數標誌
CLR F0
CLR C
RET
FTD8: MOV A,R2 ;按規定的整數位數進行右規
CJNE A,B,FTD9
MOV A,R3 ;將雙位元組結果傳送到[R0]中
MOV @R0,A
INC R0
MOV A,R4
MOV @R0,A
DEC R0
RET
FTD9: CLR C
LCALL RR1 ;右規一次
SJMP FTD8

(26) 標號: BTOF 功能:浮點BCD碼轉換成格式化浮點數
入口條件:浮點BCD碼操作數在[R0]中｡
出口信息:轉換成的格式化浮點數仍在[R0]中｡
影響資源:PSW､A､B､R2~R7､位1DH~1FH 堆棧需求:6位元組
BTOF: INC R0 ;判斷是否為零｡
INC R0
MOV A,@R0
MOV R7,A
DEC R0
MOV A,@R0
MOV R6,A
DEC R0
ORL A,R7
JNZ BTF0
MOV @R0,#41H;為零,轉換結束｡
RET
BTF0: MOV A,@R0
MOV C,ACC.7
MOV 1DH,C ;保存數符｡
CLR 1FH ;以絕對值進行轉換｡
MOV C,ACC.6 ;擴充階碼為八位｡
MOV ACC.7,C
MOV @R0,A
JNC BTF1
ADD A,#19 ;是否小於1E-19?
JC BTF2
MOV @R0,#41H;小於1E-19時以0計｡
INC R0
MOV @R0,#0
INC R0
MOV @R0,#0
DEC R0
DEC R0
RET
BTF1: SUBB A,#19
JC BTF2
MOV A,#3FH ;大於1E19時封頂｡
MOV C,1DH
MOV ACC.7,C
MOV @R0,A
INC R0
MOV @R0,#0FFH
INC R0
MOV @R0,#0FFH
DEC R0
DEC R0
RET
BTF2: CLR A ;準備將BCD碼尾數轉換成十六進位浮點數｡
MOV R4,A
MOV R3,A
MOV R2,#10H ;至少兩個位元組｡
BTF3: MOV A,R7
ADD A,R7
DA A
MOV R7,A
MOV A,R6
ADDC A,R6
DA A
MOV R6,A
MOV A,R4
RLC A
MOV R4,A
MOV A,R3
RLC A
MOV R3,A
DEC R2
JNB ACC.7,BTF3;直到尾數規格化｡
MOV A,R6 ;四捨五入｡
ADD A,#0B0H
CLR A
ADDC A,R4
MOV R4,A
CLR A
ADDC A,R3
MOV R3,A
JNC BTF4
MOV R3,#80H
INC R2
BTF4: MOV DPTR,#BTFL;準備查表得到十進位階碼對應的浮點數｡
MOV A,@R0
ADD A,#19 ;計算表格偏移量｡
MOV B,#3
MUL AB
ADD A,DPL
MOV DPL,A
JNC BTF5
INC DPH
BTF5: CLR A ;查表｡
MOVC A,@A+DPTR
MOV C,ACC.6
MOV ACC.7,C
MOV R5,A
MOV A,#1
MOVC A,@A+DPTR
MOV R6,A
MOV A,#2
MOVC A,@A+DPTR
MOV R7,A
LCALL MUL1 ;將階碼對應的浮點數和尾數對應的浮點數相乘｡
MOV C,1DH ;取出數符｡
MOV 1FH,C
LJMP MOV0 ;傳送轉換結果｡

(27) 標號: FTOB 功能:格式化浮點數轉換成浮點BCD碼
入口條件:格式化浮點操作數在[R0]中｡
出口信息:轉換成的浮點BCD碼仍在[R0]中｡
影響資源:PSW､A､B､R2~R7､位1DH~1FH 堆棧需求:6位元組
FTOB: INC R0
MOV A,@R0
INC R0
ORL A,@R0
DEC R0
DEC R0
JNZ FTB0
MOV @R0,#41H
RET
FTB0: MOV A,@R0
MOV C,ACC.7
MOV 1DH,C
CLR ACC.7
MOV @R0,A
LCALL MVR0
MOV DPTR,#BFL0;絕對值大於或等於1時的查表起點｡
MOV B,#0 ;十的0次冪｡
MOV A,R2
JNB ACC.7,FTB1
MOV DPTR,#BTFL;絕對值小於1E-6時的查表起點｡
MOV B,#0EDH ;十的-19次冪｡
ADD A,#16
JNC FTB1
MOV DPTR,#BFLN;絕對值大於或等於1E-6時的查表起點｡
MOV B,#0FAH ;十的-6次冪｡
FTB1: CLR A ;查表,找到一個比待轉換浮點數大的整數冪｡
MOVC A,@A+DPTR
MOV C,ACC.6
MOV ACC.7,C
MOV R5,A
MOV A,#1
MOVC A,@A+DPTR
MOV R6,A
MOV A,#2
MOVC A,@A+DPTR
MOV R7,A
MOV A,R5 ;和待轉換浮點數比較｡
CLR C
SUBB A,R2
JB ACC.7,FTB2;差為負數｡
JNZ FTB3
MOV A,R6
CLR C
SUBB A,R3
JC FTB2
JNZ FTB3
MOV A,R7
CLR C
SUBB A,R4
JC FTB2
JNZ FTB3
MOV R5,B ;正好是表格中的數｡
INC R5 ;冪加一｡
MOV R6,#10H ;尾數為0•1000｡
MOV R7,#0
SJMP FTB6 ;傳送轉換結果｡
FTB2: INC DPTR ;準備表格下一項｡
INC DPTR
INC DPTR
INC B ;冪加一｡
SJMP FTB1 ;
FTB3: PUSH B ;保存冪值｡
LCALL DIV3 ;相除,得到一個二進位浮點數的純小數｡
FTB4: MOV A,R2 ;取階碼｡
JZ FTB5 ;為零嗎?
CLR C
LCALL RR1 ;右規｡
SJMP FTB4
FTB5: POP ACC ;取出冪值｡
MOV R5,A ;作為十進位浮點數的階碼｡
LCALL HB2 ;轉換尾數的十分位和百分位｡
MOV R6,A
LCALL HB2 ;轉換尾數的千分位和萬分位｡
MOV R7,A
MOV A,R3 ;四捨五入｡
RLC A
CLR A
ADDC A,R7
DA A
MOV R7,A
CLR A
ADDC A,R6
DA A
MOV R6,A
JNC FTB6
MOV R6,#10H
INC R5
FTB6: INC R0 ;存放轉換結果｡
INC R0
MOV A,R7
MOV @R0,A
DEC R0
MOV A,R6
MOV @R0,A
DEC R0
MOV A,R5
MOV C,1DH ;取出數符｡
MOV ACC.7,C
MOV @R0,A
RET
HB2: MOV A,R4 ;尾數擴大100倍｡
MOV B,#100
MUL AB
MOV R4,A
MOV A,B
XCH A,R3
MOV B,#100
MUL AB
ADD A,R3
MOV R3,A
JNC HB21
INC B
HB21: MOV A,B ;將整數部分轉換成BCD碼｡
MOV B,#10
DIV AB
SWAP A
ORL A,B
RET
BTFL: DB 41H,0ECH,1EH ;1.0000E-19
DB 45H,93H,93H ;1.0000E-18
DB 48H,0B8H,78H ;1.0000E-17
DB 4BH,0E6H,96H ;1.0000E-16
DB 4FH,90H,1DH ;1.0000E-15
DB 52H,0B4H,25H ;1.0000E-14
DB 55H,0E1H,2EH ;1.0000E-13
DB 59H,8CH,0BDH ;1.0000E-12
DB 5CH,0AFH,0ECH ;1.0000E-11
DB 5FH,0DBH,0E7H ;1.0000E-10
DB 63H,89H,70H ;1.0000E-9
DB 66H,0ABH,0CCH ;1.0000E-8
DB 69H,0D6H,0C0H ;1.0000E-7
BFLN: DB 6DH,86H,38H ;1.0000E-6
DB 70H,0A7H,0C6H ;1.0000E-5
DB 73H,0D1H,0B7H ;1.0000E-4
DB 77H,83H,12H ;1.0000E-3
DB 7AH,0A3H,0D7H ;1.0000E-2
DB 7DH,0CCH,0CDH ;1.0000E-1
BFL0: DB 1,80H,00H ;1.0000
DB 4,0A0H,00H ;1.0000E1
DB 7,0C8H,00H ;1.0000E2
DB 0AH,0FAH,00H ;1.0000E3
DB 0EH,9CH,40H ;1.0000E4
DB 11H,0C3H,50H ;1.0000E5
DB 14H,0F4H,24H ;1.0000E6
DB 18H,98H,97H ;1.0000E7
DB 1BH,0BEH,0BCH ;1.0000E8
DB 1EH,0EEH,6BH ;1.0000E9
DB 22H,95H,03H ;1.0000E10
DB 25H,0BAH,44H ;1.0000E11
DB 28H,0E8H,0D5H ;1.0000E12
DB 2CH,91H,85H ;1.0000E13
DB 2FH,0B5H,0E6H ;1.0000E14
DB 32H,0E3H,60H ;1.0000E15
DB 36H,8EH,1CH ;1.0000E16
DB 39H,31H,0A3H ;1.0000E17
DB 3CH,0DEH,0BH ;1.0000E18
DB 40H,8AH,0C7H ;1.0000E19

(28) 標號: FCOS 功能:浮點餘弦函數
入口條件:操作數在[R0]中｡
出口信息:結果仍在[R0]中｡
影響資源:DPTR､PSW､A､B､R2~R7､位1DH~1FH 堆棧需求: 6位元組
FCOS: LCALL FABS ;COS(-X) = COS X
MOV R5,#1 ;常數1.5708(π/2)
MOV R6,#0C9H
MOV R7,#10H
CLR 1EH
LCALL MVR0
CLR F0
LCALL AS1 ;x+(π/2)
LCALL MOV0 ;保存結果,接著運行下面的FSIN程序

(29) 標號: FSIN 功能:浮點正弦函數
入口條件:操作數在[R0]中｡
出口信息:結果仍在[R0]中｡
影響資源:DPTR､PSW､A､B､R2~R7､位1DH~1FH 堆棧需求: 6位元組
FSIN: MOV A,@R0
MOV C,ACC.7
MOV 1DH,C ;保存自變數的符號
CLR ACC.7 ;統一按正數計算
MOV @R0,A
LCALL MVR0 ;將[R0]傳送到第一工作區
MOV R5,#0 ;係數0.636627(2/π)
MOV R6,#0A2H
MOV R7,#0FAH
CLR 1EH
LCALL MUL1 ;相乘,自變數按(π/2)規一化
MOV A,R2 ;將結果複製到第二區
MOV R5,A
MOV A,R3
MOV R6,A
MOV A,R4
MOV R7,A
LCALL INT ;第一區取整,獲得象限信息
MOV A,R2
JZ SIN2
SIN1: CLR C ;將浮點象限數轉換成定點象限數
LCALL RR1
CJNE R2,#10H,SIN1
MOV A,R4
JNB ACC.1,SIN2
CPL 1DH ;對於第三､四象限,結果取反
SIN2: JB ACC.0,SIN3
CPL 1FH ;對於第一､三象限,直接求規一化的小數
SJMP SIN4
SIN3: MOV A,R4 ;對於第二､四象限,準備求其補數
INC A
MOV R4,A
JNZ SIN4
INC R3
SIN4: LCALL RLN ;規格化
SETB F0
LCALL AS1 ;求自變數歸一化等效值
LCALL MOV0 ;回傳
LCALL FPLN ;用多項式計算正弦值
DB 7DH,93H,28H;0.07185
DB 41H,0,0 ;0
DB 80H,0A4H,64H;-0.64215
DB 41H,0,0 ;0
DB 1,0C9H,2;1.5704
DB 41H,0,0 ;0
DB 40H ;結束
MOV A,@R0 ;結果的絕對值超過1.00嗎?
JZ SIN5
JB ACC.6,SIN5
INC R0 ;絕對值按1.00封頂
MOV @R0,#80H
INC R0
MOV @R0,#0
DEC R0
DEC R0
MOV A,#1
SIN5: MOV C,1DH ;將數符拼入結果中
MOV ACC.7,C
MOV @R0,A
RET

(30) 標號: FATN 功能:浮點反正切函數
入口條件:操作數在[R0]中｡
出口信息:結果仍在[R0]中｡
影響資源:DPTR､PSW､A､B､R2~R7､位1CH~1FH 堆棧需求:7位元組
FATN: MOV A,@R0
MOV C,ACC.7
MOV 1DH,C ;保存自變數數符
CLR ACC.7 ;自變數取絕對值
MOV @R0,A
CLR 1CH ;清求余運算標誌
JB ACC.6,ATN1;自變數為純小數否?
JZ ATN1
SETB 1CH ;置位求余運算標誌
LCALL FRCP ;通過倒數運算,轉換成純小數
ATN1: LCALL FPLN ;通過多項式運算,計算反正切函數值
DB 0FCH,0E4H,91H;-0.055802
DB 7FH,8FH,37H;0.27922
DB 0FFH,0EDH,0E0H;-0.46460
DB 7BH,0E8H,77H;0.028377
DB 0,0FFH,68H;0.9977
DB 72H,85H,0ECH;3.1930×10-5
DB 40H ;結束
JNB 1CH,ATN2;需要求余運算否?
CPL 1FH ;準備運算標誌
MOV C,1FH
MOV F0,C ;常數1.5708(π/2)
MOV R5,#1
MOV R6,#0C9H
MOV R7,#10H
LCALL AS1 ;求余運算
LCALL MOV0 ;回傳
ATN2: MOV A,@R0 ;拼入結果的數符
MOV C,1DH
MOV ACC.7,C
MOV @R0,A
RET

(31) 標號: RTOD 功能:浮點弧度數轉換成浮點度數
入口條件:浮點弧度數在[R0]中｡
出口信息:轉換成的浮點度數仍在[R0]中｡
影響資源:PSW､A､B､R2~R7､位1EH､1FH 堆棧需求:6位元組
RTOD: MOV R5,#6 ;係數(180/π)傳送到第二工作區
MOV R6,#0E5H
MOV R7,#2FH
SJMP DR ;通過乘法進行轉換

(32) 標號: DTOR 功能:浮點度數轉換成浮點弧度數
入口條件:浮點度數在[R0]中｡
出口信息:轉換成的浮點弧度數仍在[R0]中｡
影響資源:PSW､A､B､R2~R7､位1EH､1FH 堆棧需求:6位元組
DTOR: MOV R5,#0FBH;係數(π/180)傳送到第二工作區
MOV R6,#8EH
MOV R7,#0FAH
DR: LCALL MVR0 ;將[R0]傳送到第一工作區
CLR 1EH ;係數為正
LCALL MUL1 ;通過乘法進行轉換
LJMP MOV0 ;結果傳送到[R0]中
END